init research

2026-02-08 11:20:43 -10:00
commit bdf064f54d
3041 changed files with 1592200 additions and 0 deletions
@@ -0,0 +1,44 @@
+plugins {
+    with(convention.plugins) {
+        alias(kotlinJvm8)
+    }
+    with(libs.plugins) {
+        alias(publisher)
+        alias(binary.compatibility.validator)
+    }
+}
+
+group = "org.jetbrains.kotlinx"
+
+dependencies {
+    api(projects.core)
+
+    implementation(libs.arrow.vector)
+    implementation(libs.arrow.format)
+    implementation(libs.arrow.memory)
+    implementation(libs.arrow.dataset)
+    implementation(libs.commonsCompress)
+    implementation(libs.kotlin.reflect)
+    implementation(libs.kotlin.datetimeJvm)
+
+    testImplementation(libs.junit)
+    testImplementation(projects.dataframeJson)
+    testImplementation(libs.kotestAssertions) {
+        exclude("org.jetbrains.kotlin", "kotlin-stdlib-jdk8")
+    }
+    testImplementation(libs.arrow.c.data)
+    testImplementation(libs.duckdb.jdbc)
+}
+
+kotlinPublications {
+    publication {
+        publicationName = "dataframeArrow"
+        artifactId = project.name
+        description = "Apache Arrow support for Kotlin DataFrame"
+        packageName = artifactId
+    }
+}
+
+tasks.test {
+    jvmArgs = listOf("--add-opens", "java.base/java.nio=ALL-UNNAMED")
+}