init commit

community/apps/talon/talon_repl/talon_repl.py

@@ -0,0 +1,19 @@
+from talon import Context, Module
+
+mod = Module()
+mod.apps.talon_repl = r"""
+win.title: /Talon - REPL/
+win.title: /.talon\/bin\/repl/
+"""
+
+ctx = Context()
+ctx.matches = r"""
+app: talon_repl
+not tag: user.code_language_forced
+"""
+
+
+@ctx.action_class("code")
+class CodeActions:
+    def language():
+        return "python"

community/apps/talon/talon_repl/talon_repl.talon

@@ -0,0 +1,56 @@
+app: talon_repl
+-
+tag(): user.talon_python
+tag(): user.readline
+
+# uncomment user.talon_populate_lists tag to activate talon-specific lists of actions, scopes, modes etcetera.
+# Do not enable this tag with dragon, as it will be unusable.
+# with conformer, the latency increase may also be unacceptable depending on your cpu
+# see https://github.com/talonhub/community/issues/600
+# tag(): user.talon_populate_lists
+
+^test last$:
+    phrase = user.history_get(1)
+    command = "sim('{phrase}')"
+    insert(command)
+    key(enter)
+^test <phrase>$:
+    insert("sim('{phrase}')")
+    key(enter)
+^test numb <number_small>$:
+    phrase = user.history_get(number_small)
+    command = "sim('{phrase}')"
+    #to do: shouldn't this work?
+    #user.paste("sim({phrase})")
+    insert(command)
+    key(enter)
+# requires user.talon_populate_lists tag. do not use with dragon
+^debug action {user.talon_actions}$:
+    insert("actions.find('{user.talon_actions}')")
+    key(enter)
+# requires user.talon_populate_lists tag. do not use with dragon
+^debug list {user.talon_lists}$:
+    insert("actions.user.talon_pretty_print(registry.lists['{talon_lists}'])")
+    key(enter)
+^debug tags$:
+    insert("actions.user.talon_pretty_print(registry.tags)")
+    key(enter)
+^debug settings$:
+    insert("actions.user.talon_pretty_print(registry.settings)")
+    key(enter)
+^debug modes$:
+    insert("actions.user.talon_pretty_print(scope.get('mode'))")
+    key(enter)
+# requires user.talon_populate_lists tag. do not use with dragon
+^debug scope {user.talon_scopes}$:
+    insert("actions.user.talon_pretty_print(scope.get('{talon_scopes}'))")
+    key(enter)
+^debug running apps$:
+    insert("actions.user.talon_pretty_print(ui.apps(background=False))")
+    key(enter)
+^debug all windows$:
+    insert("actions.user.talon_pretty_print(ui.windows())")
+    key(enter)
+^debug {user.running} windows$:
+    insert("actions.user.talon_debug_app_windows('{running}')")
+    key(enter)